Hangi yol size uygun?
Ne kadar metin çevireceğinize ve Excel sürümünüze bağlı:
| Yol | Ne için | Ne gerekir | Dosyadaki formüller |
|---|---|---|---|
| DİLÇEVİR formülü | Ne için: Tek hücre veya bütün bir sütun, Excel'den çıkmadan | Ne gerekir: Microsoft 365 için Excel (Windows, Mac) veya Excel Mobile ve internet | Dosyadaki formüller: Değişmez: çeviri yan sütunda yeni bir formül olarak durur |
| Gözden Geçir → Çevir | Ne için: Arada bir, birkaç hücredeki metin | Ne gerekir: Microsoft 365 veya Office 2021 ve sonrası, internet | Dosyadaki formüller: Dosya değişmez: çeviriyi kendiniz kopyalayıp yapıştırırsınız |
| Google E-Tablolar'da GOOGLETRANSLATE | Ne için: Excel'inizde DİLÇEVİR yoksa bir sütun metin | Ne gerekir: Google hesabı; metni Excel'den E-Tablolar'a kopyalayıp geri getirmek | Dosyadaki formüller: Google'a yalnızca kopyaladığınız metin gider |
| Dosyanın tamamı: ExcelTranslator.ai | Ne için: Bütün çalışma kitabı, seçtiğiniz sayfalar tek seferde | Ne gerekir: Tarayıcı; önizleme ücretsiz, sonra dosya başına 2,90 $'dan | Dosyadaki formüller: Formül olarak kalır, değişmez |
1. Excel'de dil çeviri formülü: DİLÇEVİR
=DİLÇEVİR(metin; [kaynak_dil]; [hedef_dil])- metin: bir hücre, örneğin A2, ya da tırnak içinde bir metin.
- kaynak_dil (isteğe bağlı): örneğin
"en". Boş bırakırsanız Excel dili kendisi algılar. Microsoft, dili biliyorsanız özellikle kısa metinlerde yazmanızı öneriyor. - hedef_dil (isteğe bağlı): örneğin
"tr". Yazmazsanız Excel sistem diline çevirir; denememizde Türkçeye çevirdi.
Microsoft'a göre işlev Microsoft 365 için Excel'de (Windows ve Mac) ve Excel Mobile'da bulunur. Çeviriyi Microsoft'un çeviri hizmeti yaptığı için internet bağlantısı gerekir.
DİLÇEVİR, ÇEVİR değil
Microsoft'un Türkçe yardım sayfasının başlığı “ÇEVİR işlevi”; Google'ın yapay zekâ özeti de =ÇEVİR(A1; "tr"; "en") formülünü veriyor. Türkçe Excel'de ÇEVİR, birimleri dönüştüren işlevdir (İngilizcesi CONVERT). Çeviri işlevinin Türkçe adı DİLÇEVİR'dir. Denememizde A1'de “Electric sit-stand desk” yazıyordu:
| Formül | Sonuç |
|---|---|
| =DİLÇEVİR(A1;"en";"tr") | Elektrikli oturma masası |
| =ÇEVİR(A1;"en";"tr") | #DEĞER! |
| =TRANSLATE(A1;"en";"tr") | #AD? |
| =ÇEVİRİ(A1;"en";"tr") | #AD? |
| =DİLİALGILA(A1) | en |
Türkçe harfleri yazamıyorsanız sorun değil: DILCEVIR ve küçük harfle dilçevir yazdığımız formülleri Excel DİLÇEVİR'e çevirdi ve çalıştırdı. Excel dosyaya İngilizce adları, TRANSLATE ve DETECTLANGUAGE'ı kaydeder; İngilizce Excel'de formül bu adlarla görünür.
Noktalı virgül mü, virgül mü?
Ayırıcı, bilgisayarın bölge ayarına bağlıdır. Excel'i Türkçe bırakıp yalnızca bölge ayarını değiştirdik:
| Bölge | Ondalık | Kabul edilen formül |
|---|---|---|
| Türkiye | 0,5 | =DİLÇEVİR(A2;"en";"tr") |
| ABD | 0.5 | =DİLÇEVİR(A2,"en","tr") |
Yanlış ayırıcıyla Excel formülü düzeltmez, hiç kabul etmez. Microsoft'un Türkçe yardım sayfasındaki söz dizimi virgüllü yazılmış; Türkiye bölge ayarında bu yazım çalışmaz.
Dil kodları
Kodlar tırnak içinde yazılır; büyük-küçük harf fark etmez ("EN" ve "TR" de çalıştı). Denediğimiz kodlar:
| Kod | Dil |
|---|---|
| "tr" | Türkçe |
| "en" | İngilizce |
| "de" | Almanca |
| "ar" | Arapça |
| "zh-Hans" | Çince (basitleştirilmiş) |
"tr-TR", "zh" ve "auto" #DEĞER! verdi. Türkçe için "tr", Çince için "zh-Hans" yazın. Google E-Tablolar'da çalışan "auto" Excel'de çalışmaz: dili Excel'e buldurmak için kaynak dili boş bırakın.
Örnekler: hücre, sütun, birkaç dil
Tek hücre
=DİLÇEVİR(A2;"en";"tr")“Please send the invoice by Friday.” → “Lütfen faturayı Cuma gününe kadar gönderin.”
Bütün sütun
Formülü B2'ye yazın ve doldurma tutamacına, yani hücrenin sağ alt köşesindeki küçük kareye çift tıklayın. Her satır A sütunundaki kendi hücresini çevirir. Yanıt gelene kadar hücrelerde #BMEŞGUL! görünür, sonra çeviri kendiliğinden gelir. Denememizde her biri tek cümle olan 150 hücrenin 100'ü 2,5 saniye sonra hâlâ bekliyordu; yaklaşık 10 saniyede hepsi tamamlandı. Sütun darsa #BMEŞGUL! yerine ####### görünebilir.
Birkaç dile birden
Dil kodlarını başlık satırına yazın, örneğin B1'e tr, C1'e de, D1'e ar; B2'ye de şunu:
=DİLÇEVİR($A2;"en";B$1)Formülü sağa ve aşağı kopyalayın: dolar işaretleri A sütununu ve 1. satırı sabit tutar. Denememizin sonucu:
| A (İngilizce) | B: tr | C: de | D: ar |
|---|---|---|---|
| Lockable filing cabinet | Kilitlenebilir dosya dolabı | Abschließbarer Aktenschrank | خزانة ملفات قابلة للقفل |
| Ergonomic office chair | Ergonomik ofis sandalyesi | Ergonomischer Bürostuhl | كرسي مكتب مريح |
| Desk lamp | Masa lambası | Schreibtischlampe | مصباح المكتب |
Dili Excel bulsun
Kaynak dili boş bırakın, ama iki noktalı virgülü koruyun:
=DİLÇEVİR(A2;;"tr")Denememizde Almanca bir cümle “Lütfen mavi sandalyeyi Cuma gününe kadar ikinci kattaki ofise teslim edin.” diye çevrildi. Hücrenin hangi dilde olduğunu görmek için =DİLİALGILA(A2) kullanın: dil kodunu döndürür, bu cümle için de, Türkçe bir metin için tr.
Türkçeden İngilizceye
=DİLÇEVİR(A2;"tr";"en")“Bu ürün stokta yok.” → “This product is out of stock.”
Hata yerine tire
Başlık satırına yanlış bir dil kodu yazılırsa hücre #DEĞER! gösterir. EĞERHATA, hatayı istediğiniz bir metinle, örneğin bir tireyle değiştirir:
=EĞERHATA(DİLÇEVİR($A2;"en";B$1);"—")Çeviriyi formülsüz bırakmak
B sütunundaki formüller A sütununa bağlıdır. A sütununu silmeden veya dosyayı göndermeden önce yalnızca çevrilmiş metin kalsın istiyorsanız B sütununu kopyalayın ve aynı yere Özel Yapıştır → Değerler ile yapıştırın.
DİLÇEVİR çalışmıyorsa
#AD?
- Neden
- Excel bu adı tanımıyor. Ya ad yanlış: denememizde TRANSLATE ve ÇEVİRİ #AD? verdi. Ya da sürümünüzde bu işlev yok: Microsoft yalnızca Microsoft 365 için Excel'i (Windows, Mac) ve Excel Mobile'ı sayıyor; lisansla bir kez satın alınan Excel 2021 ve 2024 bu listede yok.
- Ne yapmalı
- DİLÇEVİR yazın. Hata sürerse Microsoft 365'i güncelleyin veya bu sayfadaki diğer yollardan birini kullanın.
Excel formülü kabul etmiyor
- Neden
- Neredeyse her zaman ayırıcıdan: Excel'iniz noktalı virgül beklerken virgül yazılmış ya da tersi.
- Ne yapmalı
- Ayırıcıyı değiştirin (bkz. Noktalı virgül mü, virgül mü?).
#DEĞER!
- Neden
- En sık nedeni geçersiz dil kodu: denememizde
"tr-TR","zh","auto"ve"xx"#DEĞER! verdi. Metin çok uzunsa da aynı hata çıkar: 3.000 karakterlik bir hücre çevrildi, 3.100 karakterlik hücre #DEĞER! verdi. ÇEVİR yazdıysanız da #DEĞER! alırsınız, çünkü Türkçe Excel'de ÇEVİR birim dönüştürür. - Ne yapmalı
- Yukarıdaki tablodaki kodlardan birini kullanın; uzun metni birkaç hücreye bölün; ÇEVİR yerine DİLÇEVİR yazın.
#BMEŞGUL!
- Neden
- Hata değil: Excel, Microsoft'un çeviri hizmetinden yanıt bekliyor.
- Ne yapmalı
- Bekleyin, çeviri kendiliğinden gelir. 150 hücrede yaklaşık 10 saniye sürdü.
#ENGELLENDİ!
- Neden
- Excel, formülün ihtiyaç duyduğu çevrimiçi hizmete ulaşamıyor. Microsoft'a göre çeviri için internet ve Office bağlı deneyimlerinin açık olması gerekir; kapalıysa Türkçe Excel “Bağlı Deneyimler kapalı” yazar.
- Ne yapmalı
- Office gizlilik ayarlarından bağlı deneyimleri açın. Şirket bilgisayarında bunu genellikle BT ekibi yapar.
“İstek kısıtlandı”
- Neden
- Microsoft'a göre çeviri işlevinin günlük kotası aşıldı. Microsoft kotanın ne kadar olduğunu yazmıyor.
- Ne yapmalı
- Daha sonra yeniden deneyin.
Sayılar çevrilmez: denememizde 123, 123 olarak kaldı. #ENGELLENDİ! ve “İstek kısıtlandı” denememizde çıkmadı; adları Türkçe Excel'in kendi metinlerinden, nedenleri Microsoft'un yardım sayfalarından.
2. Formülsüz: Gözden Geçir → Çevir
- Çevrilecek metnin olduğu hücreyi seçin.
- Gözden Geçir sekmesinde Çevir'e tıklayın.
- Sağda açılan panelde hedef dili seçin.
- Çeviriyi kopyalayıp hücreye yapıştırın. Microsoft'a göre Excel'de, Word'deki gibi metni çeviriyle değiştiren bir Ekle düğmesi yoktur.
Microsoft'un yardım sayfası bu özelliği Microsoft 365 aboneleri ve Office 2021 için yazıyor; internet bağlantısı ve bağlı deneyimlerin açık olması gerekir. Türkçe yardım sayfasında adım “Çeviriyi Gözden Geçir'i> seçin” diye bozuk çevrilmiş; Türkçe Excel'de sekmenin adı Gözden Geçir, düğmenin adı Çevir.
Birkaç hücre için metni Google Çeviri'ye veya DeepL'e yapıştırıp çeviriyi geri kopyalamak da işinizi görür.
3. Microsoft 365 yoksa: Google E-Tablolar
GOOGLETRANSLATE Excel'de yoktur; Google E-Tablolar'ın (Google Sheets) işlevidir. Excel'inizde DİLÇEVİR yoksa bir sütunu orada çevirebilirsiniz:
- Excel'deki sütunu kopyalayıp Google E-Tablolar'da A sütununa yapıştırın.
- B2'ye GOOGLETRANSLATE yazın: hücre, kaynak dil ve hedef dil, örneğin A2,
"en"ve"tr". - Formülü aşağı sürükleyin.
- Çevrilen sütunu kopyalayıp Excel'e Özel Yapıştır → Değerler ile yapıştırın.
Google'ın Türkçe yardım sayfasındaki örneklerde hem virgül hem noktalı virgül var; kaynak dil yerine "auto" yazılabiliyor. E-Tablolar'ı biz denemedik, bu bölüm Google'ın yardım sayfasına dayanıyor. Excel'de Google Translate: formül, eklenti ve dosyanın tamamı
4. Excel dosyasının tamamını çevirmek
DİLÇEVİR ve Gözden Geçir → Çevir hücre hücre çalışır: birkaç sayfalık bir çalışma kitabında her dil için bir sütun ekleyip işi her sayfada tekrarlamanız gerekir. Aynı dosyayı formülleri ve biçimiyle başka bir dilde almak istiyorsanız dosyanın kendisini çevirmek daha kısa yoldur:
- ExcelTranslator.ai (bizim hizmetimiz): XLSX, XLS veya CSV dosyanızı yükleyin, dilleri seçin (50'den fazla dil) ve ücretsiz önizlemeye bakın. Seçtiğiniz tüm sayfalar tek seferde çevrilir, formüller formül olarak kalır; sütunları, satırları veya sayfaları çeviri dışında bırakabilirsiniz. Ücret dosya başına 2,90 $'dan başlar, abonelik yok; 3 sayfalık örnek dosyamız Lite ile 2,90 $, Pro ile 5 $ tuttu. Türkiye'den de ABD doları ile ödenir. Ücretsiz bir hesaba kayıtta 50 kredi, ardından her ay 50 kredi yüklenir. Excel dosyasının tamamını çevir
- DeepL: Excel dosyalarını yalnızca ücretli planlarda çevirir. Yardım sayfasına göre çevrilmiş dosyada formüllerin yalnızca sonucu görünür ve dosyanın belirli bölümleri çeviri dışında bırakılamaz.
- Google Çeviri: ücretsiz; bilgisayarda Dokümanlar sekmesinden en fazla 10 MB'lık .xlsx dosyalarını çevirir. Google formüllerin ve biçimin korunup korunmadığını yazmıyor.
DeepL ve Google Çeviri bilgileri 14 Kasım 2026 tarihli yardım sayfalarına dayanıyor (bkz. kaynaklar).
DİLÇEVİR'in yapamadıkları
- Kendi terimlerinizi kullanmaz. DİLÇEVİR'in sözlüğü yok. Denememizde “Electric sit-stand desk” (oturarak ve ayakta kullanılan elektrikli masa) “Elektrikli oturma masası” oldu; ayakta kullanım anlamı kayboldu.
- Çalışma kitabını çevirmez. İşlev bir hücreyi çevirir ve özgün metnin yanına formül ekler; grafik başlıkları, sayfa adları ve açıklamalar çevrilmez.
- Metin bilgisayarınızda kalmaz. Metin Microsoft'un çeviri hizmetine gider. Gizli veriler için önce bunu göndermeye izniniz olup olmadığına bakın.
Sık sorulan sorular
Excel'de çeviri formülü nedir?
Türkçe Excel'de =DİLÇEVİR(metin; [kaynak_dil]; [hedef_dil]), örneğin =DİLÇEVİR(A2;"en";"tr"). İngilizce Excel'de aynı işlevin adı TRANSLATE'tir ve virgülle yazılır: =TRANSLATE(A2,"en","tr"). Microsoft'un Türkçe yardım sayfası ve Google'ın yapay zekâ özeti işlevi ÇEVİR diye yazıyor; Türkçe Excel'de ÇEVİR birim dönüştürme işlevidir ve denememizde #DEĞER! verdi.
Excel'de İngilizce metni Türkçeye nasıl çeviririm?
Metin A2'deyse B2'ye =DİLÇEVİR(A2;"en";"tr") yazın ve formülü aşağı kopyalayın. Formül istemiyorsanız hücreyi seçip Gözden Geçir → Çevir'i kullanın. Türkçeden İngilizceye çevirmek için kodların yerini değiştirin: =DİLÇEVİR(A2;"tr";"en"). Denememizde “Bu ürün stokta yok.” → “This product is out of stock.” oldu.
Otomatik çeviri nasıl yapılır?
Bir şey kurmanız gerekmez: DİLÇEVİR, Microsoft 365 için Excel'in içinde gelir. Kaynak dili boş bırakırsanız (iki noktalı virgülü koruyarak: =DİLÇEVİR(A2;;"tr")) Excel dili kendisi algılar. Gereken tek şey internet ve Office bağlı deneyimlerinin açık olması.
DİLÇEVİR hangi Excel sürümlerinde var?
Microsoft'a göre Microsoft 365 için Excel'de (Windows ve Mac) ve Excel Mobile'da. Lisansla bir kez satın alınan Excel 2021 ve 2024'te bu formül yok, #AD? hatası verir; bu sürümlerde Gözden Geçir → Çevir kullanılabilir.
Excel için çeviri eklentisi gerekiyor mu?
Microsoft 365 kullanıyorsanız hayır: DİLÇEVİR ve Gözden Geçir → Çevir Excel'in içinde. Google Translate kullanan eklentiler üçüncü taraflarındır; Google'ın Excel için yayımladığı bir eklenti yok. Ayrıntılar Excel'de Google Translate rehberimizde.
Excel dosyasını Türkçeye nasıl çevirebilirim?
DİLÇEVİR ve Gözden Geçir → Çevir hücre hücre çalışır. Birkaç sayfalık bir çalışma kitabının tamamını aynı düzenle Türkçe almak için dosyanın kendisini çeviren bir araç daha kısa yoldur: ExcelTranslator.ai'de XLSX, XLS veya CSV dosyanızı yükleyip ücretsiz önizlemeye bakabilirsiniz; formüller formül olarak kalır.
Excel'i Türkçeye nasıl çeviririm?
Bu, metin çevirmekten farklı bir iş. Windows'ta menülerin dilini Dosya → Seçenekler → Dil'de, Office Görüntüleme Dili altından seçersiniz. Mac'te Office, macOS'un birincil dilini kullanır; dili değiştirip Excel'i yeniden başlatmanız gerekir. İşlev adları da kendiliğinden değişir.
Excel'de Türkçe ve İngilizce formül adları nelerdir?
Excel işlev adlarını arayüz dilinde gösterir, dosyaya ise İngilizce adları kaydeder. Bu yüzden Türkçe Excel'de DİLÇEVİR, DİLİALGILA, TOPLA, EĞER, DÜŞEYARA, EĞERSAY ve EĞERHATA yazan bir dosya İngilizce Excel'de TRANSLATE, DETECTLANGUAGE, SUM, IF, VLOOKUP, COUNTIF ve IFERROR olarak, noktalı virgül yerine virgülle görünür. Bu adları Türkçe Excel'de denedik.
Kaynaklar ve deneme koşulları
14 Kasım 2026'da Mac için Excel 16.115'te (Microsoft 365), arayüz Türkçe ve bölge Türkiye iken denendi; ayırıcı ayrıca bölge ABD iken denendi. Formüller bu sayfadaki gibi yazıldı. Gözden Geçir → Çevir panelini açmadık: sekme ve düğme adları Türkçe Excel'den, adımlar ve sürümler aşağıdaki Microsoft yardım sayfalarından. Google E-Tablolar'ı denemedik ve Google Çeviri'ye dosya yüklemedik. ExcelTranslator.ai fiyatları 14 Kasım 2026 tarihli önizleme fiyatlarıdır.
- Microsoft Destek: “ÇEVİR işlevi” (Türkçe Excel'de adı DİLÇEVİR)
- Microsoft Destek: DİLİALGILA işlevi
- Microsoft Destek: Metni farklı bir dile çevirme
- Microsoft Destek: Office'in menülerinde kullandığı dili değiştirme
- Google Dokümanlar Düzenleyicileri Yardım: GOOGLETRANSLATE
- Google Çeviri Yardım: Dokümanları ve web sitelerini çevirme (bilgisayar)
- DeepL Yardım Merkezi: Excel dosyalarını çevir